之前分享了Linux版本的一键安装脚本，这次分享Windows版本的一键安装Jdk和MySQL的批处理脚本，省去不必要的安装麻烦，对新手小白友好。
Jdk
install_jdk.bat
@echo off
:: 当前目录
set CURRENT_DIR=%~dp0
:: 需要安装的Java路径
set JAVA_PATH=E:\coding_environment\Java\jdk1.8
:: Java安装包名称
set JAVA_PACKAGE_NAME=jdk-8u333-windows-x64.exe
set
echo *****************************
echo.
echo 欢迎使用一键安装jdk
echo.
echo *****************************
echo.
echo 正在安装Jdk，请不要执行其他操作
echo.
echo 请稍等....
echo.
start /WAIT %CURRENT_DIR%packages\%JAVA_PACKAGE_NAME% /qn INSTALLDIR="%JAVA_PATH%"
echo.
echo 设置环境变量中...
set JAVA_HOME=%JAVA_PATH%
set CLASSPATH=.;%%JAVA_HOME%%\lib\dt.jar;%%JAVA_HOME%%\lib\tools.jar
set PATH=%PATH%;%%JAVA_HOME%%\bin;%%JAVA_HOME%%\jre\bin
set RegV=HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
reg add "%RegV%" /v "JAVA_HOME" /d "%JAVA_HOME%" /f
reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "%PATH%" /f
reg add "%RegV%" /v "CLASSPATH" /d "%CLASSPATH%" /f
echo Jdk安装完毕!
:end
pause
MySQL
install_mysql.bat
@echo off
:: 当前目录
set CURRENT_DIR=%~dp0
:: 需要安装的MySQL路径父目录
set MYSQL_PATH=E:\coding_environment\mysql
:: MySQL源目录名称
set MYSQL_SOURCE_PATH=mysql-8.0.28-winx64
:: MYSQL本地安装目录
set MYSQL_INSTALL_DIR=%MYSQL_PATH%\%MYSQL_SOURCE_PATH%
:: 服务名
set SERVICE_NAME=mysql8
:: 数据库密码
set MYSQL_PWD=lijing123456
:: 注意在mysql-8.0.28-winx64下创建data目录，以便于存放数据文件
:: 创建my.ini文件，内容参考如下
:: [mysqld]
:: # 设置3306端口
:: port=3306
:: # 设置mysql的安装目录
:: basedir=E:\coding_environment\mysql\mysql-8.0.28-winx64
:: # 设置mysql数据库的数据的存放目录，在安装mysql-5.7.30-winx64.zip版本的时候，此配置不可添加，否则mysql将无法启动。
:: datadir=E:\coding_environment\mysql\mysql-8.0.28-winx64\data
:: # 允许最大连接数
:: max_connections=200
:: # 允许连接失败的次数。这是为了防止有人从该主机试图攻击数据库系统
:: max_connect_errors=10
:: # 服务端使用的字符集默认为utf8mb4
:: character-set-server=utf8mb4
:: # 创建新表时将使用的默认存储引擎
:: default-storage-engine=INNODB
:: # 默认使用“mysql_native_password”插件认证
:: default_authentication_plugin=mysql_native_password
:: # 关闭ssl
:: skip_ssl
:: # 配置时区
:: default-time_zone='+8:00'
:: # 配置 sql mode
:: sql_mode='STRICT_TRANS_TABLES,NO_ZERO_IN_DATE,NO_ZERO_DATE,ERROR_FOR_DIVISION_BY_ZERO,NO_ENGINE_SUBSTITUTION'
:: [mysql]
:: # 设置mysql客户端默认字符集
:: default-character-set=utf8mb4
:: [client]
:: # 设置mysql客户端连接服务端时默认使用的端口
:: port=3306
:: default-character-set=utf8mb4
echo *****************************
echo.
echo 欢迎使用一键安装mysql
echo.
echo *****************************
echo.
echo 正在安装mysql，请不要执行其他操作
echo.
echo 请稍等，安装过程可能会持续一会儿...
echo.
:: 检查MySQL服务是否存在，如果存在则停止删除服务
echo 检查是否有服务%SERVICE_NAME%
sc query %SERVICE_NAME% > nul
if errorlevel 1060 (
echo 服务 %SERVICE_NAME% 不存在
) else (
echo 服务 %SERVICE_NAME% 存在
echo 停止已存在的服务MySQL
net stop %SERVICE_NAME%
echo 删除已存在的服务MySQL
sc delete %SERVICE_NAME%
echo 删除服务执行文件项
reg delete HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\%SERVICE_NAME% /v ImagePath /f
)
reg delete HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\mysql8 /v ImagePath /f
echo 开始执行安装MySQL步骤...
:: 将准备好的 MySQL 免安装包复制到磁盘指定的位置
echo 拷贝准备好的免安装包到磁盘指定位置...
:: 如果目录已存在则
if exist %MYSQL_INSTALL_DIR% (
echo 指定安装目录已存在
) else (
mkdir %MYSQL_INSTALL_DIR%
xcopy %CURRENT_DIR%packages\%MYSQL_SOURCE_PATH% %MYSQL_INSTALL_DIR% /e /y
)
:: 设置环境变量
echo 设置环境变量中...
set PATH=%PATH%;%%MYSQL_HOME%%\bin
set RegV=HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
reg add "%RegV%" /v "MYSQL_HOME" /d "%MYSQL_INSTALL_DIR%" /f
reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "%PATH%" /f
:: 安装启动MySQL服务
echo 安装数据库服务...
%MYSQL_INSTALL_DIR%\bin\mysqld.exe -install "mysql8"
:: 添加服务执行文件项
echo 添加服务执行文件项...
REG add HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\%SERVICE_NAME% /v ImagePath /t REG_EXPAND_SZ /d "%MYSQL_INSTALL_DIR%\bin\mysqld.exe --defaults-file=\"%MYSQL_INSTALL_DIR%\my.ini\" %SERVICE_NAME%" /f
echo 正在初始化MySQL8...
%MYSQL_INSTALL_DIR%\bin\mysqld.exe --initialize-insecure
:: 启动MySQL8
echo 正在启动mysql8...
net start mysql8
:: 设置修改数据库密码
echo 修改数据库密码...
%MYSQL_INSTALL_DIR%\bin\mysqladmin.exe -uroot -p password %MYSQL_PWD%
echo mysql8安装成功！
:end
pause
评论区